**MOSDEX Syntax**

**Version 1-0**

Dr. Jeremy A. Bloom  
[jeremyblmca@gmail.com](mailto:jeremyblmca@gmail.com)  
June 6, 2019

**Synopsis of Changes In v1-0 vs. v0-3**

* MOSDEX syntax has been re-envisioned based on development of many examples. Many changes have been made to simplify and generalize the representation of optimization problems and to improve readability.
* Sections and type tags for Problems and Tables have been removed. A MOSDEX file has Problems as its only named objects, and a Problem now has Tables as its only named objects. As a result, the parser can infer the type of a named object before parsing it.
* A mathematical Expression section has been added to the Heading object, which was also renamed from Header.
* Arrays of strings are used extensively in place of ordinary strings in order to allow multi-line format and other segmentation of string information.
* Instance has replaced Rows as the data container in an instance form Table.
* Singleton provides a compact representation of an instance form table with a single record.
* SQL queries have separate clauses for Select, From, etc., to facilitate working with database managers that do not natively accept SQL query strings.
* Properties object has been removed from modeling objects, and the information it contained has been placed into fields of the object’s schema.
* Fields for solver results have been added to the modeling objects.
* The Modules object has been removed, and its functions have been replaced by Import, Index, For Each, and other dispersed objects more closely identified with the objects they affect.
* Path names and string substitutions have been implemented.

1. **Introduction and Overview**

This paper defines a formal syntax for MOSDEX. We use extended Backus-Naur form (EBNF) (see <https://en.wikipedia.org/wiki/Extended_Backus%E2%80%93Naur_form>) and also present the corresponding syntax diagrams.

At the highest level, a MOSDEX file is a collection of optimization *Problems*, each of which in turn is a collection of *Tables*. A Table represents a table in a relational database. Subclasses of Table represent Data and modeling objects, such as Variables and Constraints. Every Table has a *Schema*, which defines its fields and their data types. Data tables can have any reasonable schema, while the schemas of the modeling objects are largely fixed by the requirements of an optimization solver. A Table can have either *instance* or *recipe* form. Instance form tables contain data while recipe form tables use SQL queries to reshape and populate data from other tables. MOSDEX can link problems together in a *modular* *structure*, to represent, for example, decomposition or stochastic programs.


1. **JSON and Primitive Types**

MOSDEX is a derivative of JavaScript Object Notation (JSON), and therefore, MOSDEX files adhere to the JSON standard (see <http://json.org/>). JSON has three fundamental elements: *objects,* *arrays,* and *primitives*.

An object is an unordered list of *key* : *element* pairs, or *members*, where each key, or *field name*, is a string; it is enclosed within curly braces, { and }, and a member’s key and element are separated by a colon, with the object’s members separated by commas. Keys must be unique within an object. In MOSDEX, the field name is always either an *identifier* or a *keyword*. These tokens are discussed in a subsequent section.

(Syntax Diagrams made with Railroad Diagram Generator by Gunther Rademacher at <https://bottlecaps.de/rr/ui>.)

Figure **: JSONObject:**




JSONObject ::= '{' ( JSONMember ( ',' JSONMember )\* )? '}'

Figure : **JSONMember:**



JSONMember ::= FieldName ':' JSONElement


Figure : **FieldName:**



FieldName ::= Identifier | Keyword

An array is an ordered list of elements; it is enclosed in square brackets, [ and ], and the elements are separated by commas. Array elements may be of mixed types.


Figure : **JSONArray:**



JSONArray ::= '[' (JSONElement ( ',' JSONElement)\* )? ']'

In both objects and arrays, the elements are either primitive types or other objects or arrays.


Figure : **JSONElement**:



JSONElement ::= JSONObject | JSONArray| JSONPrimitive

JSON supports the following primitive types: strings of Unicode characters enclosed in double quotes, decimal integers, decimal floating point numbers with or without an exponent, boolean (true or false), and null. Boolean is not used in MOSDEX.


Figure : **JSONPrimitive:**



JSONPrimitive ::= String | Number


Additionally, MOSDEX allows two other number types. Binary (zero or one) values are a subtype of integers used in mathematical expressions, especially as decision variables in optimization models; note that the binary type differs from the boolean type, which is used in logical expressions. IEEE doubles are represented as strings of hexadecimal digits, as well as the special values +/- infinity and NaN, according to the IEEE 754 standard; IEEE doubles are represented as JSON strings, since neither standard JSON parsers nor most databases support this type; MOSDEX parsers should convert them to ordinary doubles, and most programming languages support this conversion. Because optimization solvers use this format, it provides the most precise way to exchange numerical data with a solver.

Figure : **Number:**




Number ::= Binary | Integer | Double | IEEEDouble

Figure : **IEEEDouble:**



IEEEDouble ::= '"' ( 'NaN' | 'Infinity' | '-Infinity' | '-'? ( '0x0.0p0' | '0x1' '.' HexDigit+ 'p' '-'? Integer ) ) '"'


Figure : **HexDigit:**



HexDigit ::= [0-9a-fA-F]

JSON and MOSDEX do not support multiline string literals; however, they both support arrays of strings, which serve the same purpose. A MOSDEX parser will generally convert an array of strings into an ordinary string by concatenation, usually embedding a context appropriate separator, such as newline, between the components.

Figure : **ArrayOfStrings**:



ArrayOfStrings::= '[' ( String ( ',' String )\* )? ']'

JSON generally ignores white space between tokens.


The JSON standard does not support comments, but many parsers support them. MOSDEX allows two kinds of C or Java-style comments:

* // ignores the rest of a line, and
* the pair /\* and \*/ ignores everything in between including line breaks.

1. **Keywords and Identifiers**


MOSDEX field names in JSON objects are either *keywords*, assuming that no keyword is repeated in a JSON object, or they are *identifiers*. An identifier generally follows the rules for identifiers in JavaScript. Usually a keyword denotes the type of the item which follows it. Where a keyword names an element, it is also used as the name of the corresponding parsing rule. MOSDEX keywords are strings written in all capital letters and can include underscore and hyphen characters.

Figure : **Keyword:**



Keyword ::= [A-Z] ([A-Z]|'\_'|'-')\*

Figure : **Identifier:**




Identifier ::= ([a-z]|[A-Z]|'\_') ([a-z]|[A-Z]|[0-9]|'\_')\*

In MOSDEX, the element following a field name is frequently, but not always, a JSON object. If the field name is a keyword, the element is called a *keyword* *object*, and its type is the keyword, which is parsed by the corresponding rule. On the other hand, if the field name is an identifier, the element is called a *named* *object*, and its type must be deduced from its context; the parser cannot read its type before it has been parsed, so all named objects within a MOSDEX object must be parsed by the same rule. (Named objects typically have a CLASS field, but it is only read while the object is being parsed.) For this reason, the only named objects allowed in a MOSDEX file are Problems, and the only named types allowed in a Problem are Tables. However, a Table can also contain keyword objects, as long as only one instance of a particular keyword object appears in a Table.

1. **Problems**

At the highest level, a MOSDEX file (we use the term file generically for any input source) is a JSON Object consisting of a collection of named Problem objects. It is useful to think of a Problem as a self-contained presentation of the data and modeling objects for a mathematical optimization problem; however, MOSDEX can actually accommodate more general structures. When model/data separation is used, the data may be presented in one or more separate Problems, without modeling objects. A decomposition of a mathematical optimization problem can be presented as a collection of MOSDEX Problems linked in a modular structure. Although not addressed in this document, a syntax for a simulation model could be defined within a MOSDEX Problem to accommodate a combined optimization/simulation model. The term Problem was chosen, as opposed to Model or Instance, because a variety of specifications are permitted in MOSDEX; a model may or may not be present in MOSDEX and data and modeling objects may be presented in either recipe or instance form.


Figure : **MOSDEX\_File:**



MosdexFile::= '{' PROBLEM ( ',' PROBLEM )\* '}'

A MOSDEX Problem is a collection of named Tables representing data and modeling objects, as well as several, mostly optional keyword objects.


Figure : **Problem:**



PROBLEM::= '"' Identifier '"' ':' '{' '"CLASS"' ':' '"PROBLEM"' ',' HEADING ',' ( SOLVER\_PARAMETERS ',' )?   
( PATHS ',' )? Table ( ',' Table )\* '}'

A Heading collects information about a problem or table; it is mandatory for a problem and optional for a table. Of the information in the Heading, only the description is mandatory. The other items in the Heading are a Version number, a Reference, which is typically a link or a citation to the source of the problem, the Author’s name and contact information, legal Notices, such as a copyright or a license and a mathematical Expression of the problem or modeling object, in any suitable language, such as OPL, AMPL, or GAMS. Note that the information in the Heading, including the Expression, are not otherwise processed by MOSDEX.

Figure : **HEADING:**




HEADING::= '"HEADING"' ':' '{' DESCRIPTION ( ',' ProblemInformation )\* ( ',' NOTICES )?   
( ',' EXPRESSION )? '}'

Figure : **Description:**



Description ::= '"DESCRIPTION"' ':' ArrayOfStrings

Figure : **ProblemInformation:**



ProblemInformation ::= ( '"VERSION"' | '"REFERENCE"' | '"AUTHOR"' ) ':' String

Figure : **Notices:**



NOTICES ::= '"NOTICES"' ':' ArrayOfStrings


Figure :



EXPRESSION ::= '"EXPRESSION"' ':' ArrayOfStrings

Solver Parameters is an optional object, which if present in a problem, provides solver-specific parameters in the form of *key* : *value* pairs. MOSDEX does not prescribe the parameter names nor their allowed values, as they can vary among solvers, but it passes them to the solver without parsing them. Multiple objects within Solver Parameters are permitted, each tagged with an identifier denoting the target solver.

Figure : **SOLVER\_PARAMETERS**:



SOLVER\_PARAMETERS ::= '"SOLVER\_PARAMETERS"' ':' '{' Identifier ':' JSONObject   
( ',' Identifier ':' JSONObject )\* '}'

Paths, also an optional object, provides a means to reference external files in a MOSDEX file. The Paths object specifies a list of variable names that can be used in string substitution within a MOSDEX problem (see the section on Modular Structure below). The calling program of MOSDEX will pass the actual values of these name variables to MOSDEX. Usually the actual values will be paths or URLs appropriate for the operating system running the application that uses MOSDEX. Thus, for instance, the data for an optimization problem could be supplied in a separate MOSDEX file that is connected at run time.

Figure : **PATHS:**



PATHS ::= '"PATHS"' ':' ArrayOfStrings

1. **Table Instances and Recipes**

Table is the base class for almost all MOSDEX named objects (except, notably, for Problem). Conceptually, a table is a two-dimensional object with a fixed number of columns, or *fields*, and an indefinite number of rows, or *records*; think of a table in a relational database. Data and modeling objects are subclasses of Table.

Figure : **Table:**





Table ::= '"' Identifier '"' ':' '{' CLASS ',' ( HEADING ',' )? ROLE ','   
( ( IMPORT\_FROM | INITIALIZE\_FROM ) ',' )? ( INDEX ',' )? ( SCHEMA ',' )? ( ',' FOR\_EACH )?   
( INSTANCE | SINGLETON | RECIPE ) ( ',' EXPORT\_TO )? '}'

A Table has a Class field that identifies the type of the object it embodies. Since the MOSDEX parser reads a Table before knowing its Class, the Class does not affect how the Table is parsed. However, once a Table is parsed, MOSDEX will check its validity, so for instance, certain fields must be present in the schema of a Variable while others must be present for a Constraint.

Figure : **CLASS:**




CLASS ::= '"CLASS"' ':' ( '"DATA"' | '"VARIABLE"' | '"CONSTRAINT"' | '"OBJECTIVE"' | '"COEFFICIENT"' )

Defer discussion of the other, subsidiary keyword fields of Table for now, to focus on the most important content.

Every Table has a *schema* which defines the names and types of its fields. Schema fields must have primitive data types; neither objects nor arrays are permitted as table elements. The schema of a Table may be specified explicitly by a Schema object; however, under certain circumstances, an explicit Schema is not required, although one may be supplied for clarity. The circumstances when a Schema is optional include:


1. The Table is imported or initialized from another Problem.
2. The Table is specified by an SQL Recipe, in which case the schema is generated by the query.
3. The Table is specified as a Singleton instance, in which case, the schema is inferred from the data as explained below.

Figure : **SCHEMA:**



SCHEMA ::= '"SCHEMA"' ':' '{' Field ( ',' Field )\* '}'

Figure : **Field:**




Field ::= '"' Identifier '"' ':' ( '"STRING"' | '"DOUBLE"' | '"INTEGER"' | '"BINARY"' | '"IEEEDOUBLE"' )

A Table may be specified in either of two forms, *Instance* or *Recipe*. In Instance form, the Table directly specifies the data that it encompasses. In Recipe form, the Table uses SQL to specify how the data are constructed from other Tables or from an external database. Both forms of Tables may coexist in a MOSDEX problem, but an individual Table must have one form or the other. A Singleton form Table is a subtype of Instance that specifies a single record instance compactly.


An Instance is a JSON Array of Records, each of which is itself a JSON Array that contains actual data. In an Instance object, the individual items in each Record are unlabeled and can only be parsed using the Table’s schema. The array of Records may be preceded by a Fieldsarray, which repeats the schema’s field names, and can be used as a visual guide for a human reader, but it does not convey any new information beyond the Schema and is not parsed by MOSDEX.

Figure : **Instance:**




INSTANCE ::= '"INSTANCE"' ':' '{' SCHEMA ( ',' FIELDS? ',' ROWS )? '}'

Figure : **Record:**



Record ::= '[' JSONPrimitive ( ',' JSONPrimitive )\* ']'


Figure : **FIELDS:**



FIELDS ::= '"FIELDS"' ':' '[' Identifier ( ',' Identifier )\* ']'

A Singleton object is a subtype of Instance that provides a simplified, compact representation of a table having a single record, a common special case that warrants separate treatment. A Singleton object is a JSON Object, so it has labels on the items in the record. The labels constitute the field names of the Singleton’s schema. The field types (which again are limited to JSON Primitives) are inferred by the parser.

Figure : **SINGLETON:**



SINGLETON ::= '"SINGLETON"' ':' '{' Item ( ',' Item )\* '}'


Figure : **Item:**



Item ::= '"' Identifier '"' ':' JSONPrimitive


As an alternative to Instance form, a MOSDEX Table can also be specified in Recipe form, which uses SQL to specify how the data are constructed from other Tables or from an external database. Using Recipe form Tables presupposes that a database engine is present in the software stack that supports the optimization application; MOSDEX does not supply database management software. In its simplest form, a Recipe is simply a Query string (or array of strings) that can be interpreted directly by the database engine. It is recommended that such queries adhere as closely as possible to ANSI standard SQL, as many database engines support it. However, not all database management systems natively support SQL of any flavor (e.g. Python Pandas), so MOSDEX also allows breaking a query into its component clauses in order to enable adapting to such systems. MOSDEX provides tags for the most common SQL clauses used in optimization modeling; however, MOSDEX does not actually parse SQL, leaving that task to the database engine.

Figure : **RECIPE:**



RECIPE ::= '"RECIPE"' ':' '{' SQL ( ',' SQL )\* '}'

Figure : **SQL:**



SQL ::= '"' ( '"QUERY"' | '"SELECT"' | '"FROM"' | '"WHERE"' | '"JOIN"' | '"UNION"' ) '"' ':' ArrayOfStrings


Returning to the discussion of the other, subsidiary keyword fields, a Table may have an optional Heading for documentation. Headings are discussed under the Problems section. A Table also has a Role, which identifies the phase of the optimization process in which it is used.

A caveat concerning the use of Instance form Tables in an output role: Since output usually depends on the solution of the Problem obtained by the solver, it is not possible to create an output instance when MOSDEX is parsed, which must occur before the solver acts in order to create the optimization objects it uses. Thus, even in Instance form, an output table is essentially a recipe for construction. However, since one cannot depend on the solver including an SQL engine, the “recipe” for an output instance table must be very simple:

1. the From clause is limited to a single table,
2. the Select clause can only include fields that are present in that table (possibly relabeled),
3. the Where clause can only include simple logical constraints
4. Joins and Unions are not allowed.

In essence, the recipe would be implemented by a simple iterator over a single solver object.

Figure : **ROLE:**



ROLE ::= '"ROLE"' ':' ( '"INPUT"' | '"OUTPUT"' | '"OPTIMZATION"' )

MOSDEX accommodates data/model separation and modular structures by enabling a Table to refer to objects external to the Problem of which it is a member. Import copies the table from a location specified by its argument string. Initialize performs the same function, but enables updates on subsequent uses in an iterative solver procedure. Such processes are discussed in the section on Modular Structure. Export performs the opposite function, exposing a Table to another Problem. The strings in the element portion of these objects may use string substitution to access Tables in MOSDEX files identified by a Path name connected by the MOSDEX caller at run-time.

Figure : **IMPORT\_FROM:**



IMPORT\_FROM ::= '"IMPORT\_FROM"' ':' ArrayOfStrings

Figure : **INITIALIZE\_FROM:**



INITIALIZE\_FROM ::= '"INITIALIZE\_FROM"' ':' ArrayOfStrings

Figure : **EXPORT\_TO:**



EXPORT\_TO ::= '"EXPORT\_TO"' ':' ArrayOfStrings

The Index and ForEach fields of Table enable functions of Modular Structure and are discussed there.

1. **Modeling Objects and their Standard Schemas**

The MOSDEX modeling classes, subclasses of Table, are Variable, Constraint, Objective, and Coefficients; they can be given in either instance or recipe form. While a MOSDEX Data object may have any reasonable schema, each type of MOSDEX modeling object has a *standard schema* that enables realizing the object in a solver. While there is no standard for a solver’s modeling API, most solvers have similar APIs, so the MOSDEX standard schemas should suffice in most cases. Recipe form modeling objects do not specify a schema explicitly, but rather the schema is inferred from the query that generates it. Thus, each query should mirror the standard schema of the given modeling object.


While each type of modeling object has unique fields, there are a number of commonalities. First, in most cases, a modeling object represents an entire category rather than a singular occurrence, because most large optimization problems have an indexed structure. That is, for instance, a network model has nodes and arcs, with flow variables defined over the arcs and balance constraints defined over the nodes. In traditional mathematical notation, the flow variables would have an index, or *key*, representing the arcs, and the balance constraints would have a key representing the nodes. Algebraic modeling languages realize this notation in their syntax. In MOSDEX, the modeling objects represent these indexes (which can have multiple components) by a set of *key* *fields* drawn from one or more Tables representing the index sets. The key fields and their corresponding index sets differ according to the particulars of the model, but the schemas of the modeling objects include them.

Second, the standard form, or *tableau*, of an optimization problem that is submitted to a solver has a two-dimensional structure, with columns representing variables and rows representing constraints. A key challenge is how to encode the multidimensional keys of a model into a two-dimensional tableau; automating this encoding is key reason for adopting an algebraic modeling language. MOSDEX does not explicitly define how this encoding is to be done (although as discussed in the section on Interactions with Solvers below, MOSDEX suggests a method), but it does specify that the schemas of the modeling objects contain fields corresponding to the tableau entry for each object’s key. MOSDEX does not parse the components of an encoding.

Third, the solver will compute a solution (or more than one) for the problem, and the modeling object’s schemas should give the solver fields in which to report the solution and auxiliary information, such as the value of each variable, its reduced cost and basis status, the dual value (for continuous problems), and slack for each constraint, the value of the objective function, and so on. The solution fields are initially set to null, which are populated in a post-processing phase of the solution process.


Finally, since the solver will read the MOSDEX modeling objects to create its own internal representation of the Problem, each record in a Table should contain the information required to construct the internal representation. While each solver has its own syntax, there is enough commonality among most solvers to establish a standard schema for each type of modeling object in MOSDEX.

Figure : **VariableSchema:**




VariableSchema ::= '"SCHEMA"' ':' '{' NameField ',' VariableType ',' ( KeyField ',' )\* ColumnEncoding ','   
( BoundField ',' )\* ValueField '}'

Figure : **ConstraintSchema:**



ConstraintSchema ::= '"SCHEMA"' ':' '{' NameField ',' ConstraintType ',' ( KeyField ',' )\* RowEncoding ',' ConstraintSense ',' RHSField '}'

Figure : **ObjectiveSchema:**



ObjectiveSchema ::= '"SCHEMA"' ':' '{' NameField ',' ConstraintType ',' ( KeyField ',' )\* RowEncoding ',' ConstantField ',' ObjectiveSense ',' ValueField '}'

Figure : **CoefficientSchema:**



CoefficientSchema ::= '"SCHEMA"' ':' '{' RowEncoding ',' ( ColumnEncoding ',' )+ EntryField '}'


The coefficient schema permits one or more column index fields, representing the possibility that it could involve more than one variable, to enable future MOSDEX extensions to quadratic and some other non-linear optimization problems.

Figure : **NameField:**




NameField ::= '"' Identifier '"' ':' '"STRING"'

Figure : **VariableType:**




VariableType ::= '"Type"' ':' ( '"CONTINUOUS"' | '"INTEGER"' | '"BINARY"' )

Figure : **ConstraintType:**




ConstraintType ::= '"Type"' ':' ( '"LINEAR"' | '"QUADRATIC"' )

Figure : **ConstraintSense:**




ConstraintSense ::= '"Sense"' ':' ( '"LE"' | '"EQ"' | '"GE"' | '"<="' | '"=="' | '">="' )

Figure : **ObjectiveSense:**



ObjectiveSense ::= '"Sense"' ':' ( '"MINIMIZE"' | '"MAXIMIZE"' | '"FREE"' )


Figure : **KeyField:**



KeyField ::= '"' Identifier '"' ':' ( '"STRING"' | '"INTEGER"' )


Tableau Encodings come in two varieties, Row Encoding and Column Encoding. Note that, as discussed above, there may be multiple column indexes, which are distinguished by an integer suffix.

Figure : **TableauEncoding:**



TableauEncoding ::= '"' ( 'Row' | 'Column' [0-9]\* ) '"' ':' ( '"STRING"' | '"INTEGER"' )

Figure : **NumberField:**



NumberField ::= ( '"LowerBound"' | '"UpperBound"' | '"RHS"' | '"Constant"' | '"Entry"' | '"Value"' ) ':'   
( '"INTEGER"' | '"DOUBLE"' | '"IEEEDOUBLE"' )

1. **Modular Structure**

Modular structures occur when a Problem, called the *parent*, embeds other Problems, called the *children*. Modular structures arise in such model constructs as block structures, decomposition algorithms, and stochastic programs. A child problem may be part of the same MOSDEX file as the parent, or it may be part of a linked file. In MODEX, the parent is responsible for mapping its tables onto the corresponding tables of the child; the child usually has little or no knowledge of the parent’s structure. In fact, the child could in most cases be optimized as a stand-alone problem.

It is important to understand that MOSDEX itself does not provide an algorithm for solving modular problems; that is the province of a solver. For example, setting up a column generation structure in MOSDEX will not be sufficient for an ordinary solver of linear programs to execute the decomposition. The solver part of the software stack must have a control structure that alternately solves the master problem and subproblems, checks the convergence criterion, and terminates the solve process. Furthermore, the solver algorithm’s requirements will determine, in part, how the problems are set up in MOSDEX. What MOSDEX does provide are standards to specify the modules that the solver executes, how they exchange data and coordinate during execution.

MOSDEX provides several constructs that enable building modular structures. First, as discussed above, a Table can be Imported from, Initialized from, or Exported to another Problem. If the target is a Table in another Problem within the same MOSDEX file, a Table reference of the form

*ProblemName.TableName*

is used. However, if the target Table is in a separate file, the form of the Table reference is

*Path/ProblemName.TableName*

where the Path is a path string or URL in the relevant operating system (most programming languages provide facilities for managing paths). Good programming practice also discourages hard-wiring properties such as path strings in code, so MODEX provides a Paths object to define *symbolic* names for paths that can be bound to actual path strings by the caller of the MOSDEX file. The actual path strings are substituted for these names by the MOSDEX parser using *string* *substitution*.

As the second construct for supporting modular structure, MOSDEX provides a limited capability to use *string* *variables*. In MOSDEX, a string beginning with a $ sign denotes a string variable. The parser will substitute a string variable with an actual string as it processes a MOSDEX file. MOSDEX permits string variables in two situations:

1. To substitute a path string for a path name in a Table reference, which usually occurs in an Import, Initialization, or Export or in the From clause of an SQL query. In this case, the path name must be declared (without the $ sign) in a Paths object.
2. To substitute an actual value for an index variable, which usually occurs in a Select, Where, or On clause of an SQL query. In this case, the index variable must be declared (without the $ sign) in Index object within a Table. Indexes are discussed below.

When a string variable is used, it should appear as a stand-alone component in an array of strings; the parser does not attempt to locate string variables embedded within strings.

As the third construct for supporting modular structure, MOSDEX provides a capability to use *Index* *variables*. It is frequently the case that the parent problem will want to incorporate multiple versions of a child problem. For example, in a multi-commodity flow problem, there could be multiple versions of a minimum cost flow problem, one for each product. Index variables deal with this common situation. An index variable is defined by an Index object within a Table and is bound to that Table as its *index* *set*; the index variable represents the records of its index set.

An index variable is called by For Each objects in other Tables. The For Each object in effect creates a loop in which the host Table is reproduced for each different index value, that is, for each record in the index set corresponding to the index variable. Usually the reproduced tables will be collected by a Union or Outer Join clause in an SQL query, since MOSDEX does not support arrays of Tables; as mentioned above, string substitution is used to refer to an index variable in an SQL query. When multiple Tables all use a For Each object with the same index variable, the MOSDEX parser in effect executes them in parallel, so that each table is reproduced for the given index value before the parser moves on to the next value.

Figure : **INDEX:**

****

INDEX ::= '"INDEX"' ':' Identifier

Figure : **FOR\_EACH:**

****

FOR\_EACH ::= '"FOR\_EACH"' ':' Identifier

1. **Interactions with Solvers**

As a standard for data exchange, MOSDEX is designed to interoperate with many different mathematical optimization solvers in many different programming languages. Its design therefore necessarily abstracts the features of the particular solvers, so that each solver will need a bridge between MOSDEX and its own API. Because most of the solvers of interest have similar APIs, the bridge software will usually be fairly similar and straightforward to write, especially because MOSDEX handles much of their structure already. Generally, many solvers already have a *modeling API*, a set of classes that are used to construct the internal representations of the variables, constraints, and objectives of an optimization problem. Since MOSDEX has similar objects, the MOSDEX parser would need to call the bridge to map its modeling objects onto those of the target solver. Some solvers have a low level interface that uses a tableau (row and column) representation of an optimization problem, either as its main interface or as a supplement to the modeling interface. With a fairly straightforward bridge, MOSDEX can accommodate a tableau representation as well.

In either case, modeling API or tableau, a critical decision is how to encode the rows and columns, as discussed in the section on MOSDEX’s modeling objects and their schemas. MOSDEX does not specify how this encoding is done, to leave some freedom to adapt to a particular solver. The example problems that have been developed to guide the syntax formulation have used strings of the form

*objectName\_key1\_...keyN*

where the object name is the name of the variable, constraint, or objective, and the keys are the values of the key fields of the particular object. This form has the advantage of providing readable column and row identifiers for debugging purposes. However, some solvers many not allow strings or may limit the length of strings used for that purpose. As an alternative, MOSDEX users might want to consider assigning consecutive non-negative integers to the rows and columns. In addition to the difficulty of interpreting the codes, counting the items in large data set is problematic. However, if necessary, MOSDEX can accommodate either strings or integers to encode rows and columns.

MOSDEX also needs to capture and structure the solution information from the solver into its output tables. MOSDEX offers two ways to accomplish this task. First, as discussed in the section on modeling objects and their schemas, each object can define fields to be populated by the solver. For variables, typically these fields would include its optimal value, and possibly its reduced cost and basis status. For constraints, they could include its dual value (for continuous problems) and slack. For objectives, they would include the optimal value.

As an alternative, MOSDEX presumes the existence of methods in the bridge classes that return values from the solver. The form of these method calls is

*getXXX(code)*

where XXX stands for Variable, Objective, Dual, etc., and code is the relevant column or row identifier. In the examples, these calls are inserted as strings in the Instance or Recipe representing the output table.

1. **Conclusion**

To be written

**Appendix 1: MOSDEX Examples**

The following example problems have been used in creating this MOSDEX syntax and should be read along with this specification document:

volsayNew2.json – a simple 2-varaible, 3-constraint linear program illustrating instance form tables

net1aNew.json – a network flow linear program illustrating recipe form tables

net1bNew.json – the same network flow linear program using instance form tables

sailcoNew.json – a production planning linear program illustrating lagged inventory decision variables

warehousingNew.json – a facility location mixed-integer linear program illustrating a large-scale, structured problem in recipe form

multicommodity.json – a multi-commodity network flow linear program in extensive form

multinetNew.json – the same multi-commodity flow problem using modular structure

cuttingStockNew.json – a cutting-stock mixed-integer linear program illustrating use of modular structure for decomposition in a column generation algorithm

**Appendix 2: MOSDEX Parsing Rules Compilation**

1. JSONObject::= '{' (JSONMember (',' JSONMember)\*)? '}'
2. JSONMember::= FieldName ':' JSONElement
3. FieldName::= ('"' Identifier '"') | ('"' Keyword '"')
4. JSONArray::= '[' (JSONElement (',' JSONElement)\*)? ']'
5. ArrayOfStrings::= '[' (String (',' String)\*)? ']'
6. JSONElement::= JSONObject | JSONArray |JSONPrimitive
7. JSONPrimitive::= String | Number
8. Number::= Binary | Integer | Double | IEEEDouble
9. IEEEDouble::= '"' ('NaN' | 'Infinity' | '-Infinity' | ('-')?'0x0.0p0' | (('-')? '0x1' '.' (HexDigit)+ 'p' ('-')? Integer)) '"'
10. HexDigit::= [0-9a-fA-F]
11. Identifier::= ([a-z]|[A-Z]|'\_') ([a-z]|[A-Z]|[0-9]|'\_')\*
12. Keyword::= [A-Z] ([A-Z]|'\_'|'-')\*
13. MosdexFile::= '{' PROBLEM (',' PROBLEM)\* '}'
14. PROBLEM::= '"' Identifier '"' ':' '{' '"CLASS"' ':' '"PROBLEM"' ',' HEADING (',' SOLVER\_PARAMETERS)? (',' PATHS)? ',' Table (',' Table)\* '}'
15. HEADING::= '"HEADING"' ':' '{' DESCRIPTION (',' ProblemInformation)\* (',' NOTICES)? (',' EXPRESSION)? '}'
16. DESCRIPTION::= '"DESCRIPTION"' ':' ArrayOfStrings
17. ProblemInformation::= ('"VERSION"' | '"REFERENCE"' |'"AUTHOR"') ':' String
18. NOTICES::= '"NOTICES"' ':' ArrayOfStrings
19. EXPRESSION::= '"EXPRESSION"' ':' ArrayOfStrings
20. SOLVER\_PARAMETERS::= '"SOLVER\_PARAMETERS"' ':' '{' Identifier ':' JSONObject (',' Identifier ':' JSONObject)\* '}'
21. PATHS::= '"PATHS"' ':' ArrayOfStrings
22. Table::= '"' Identifier '"' ':' '{' CLASS (',' HEADING)? ',' ROLE (',' (IMPORT\_FROM | INITIALIZE\_FROM))? (',' INDEX)? (',' SCHEMA)? ',' (',' FOR\_EACH)? (INSTANCE | SINGLETON | RECIPE) (',' EXPORT\_TO)?'}'
23. CLASS::= '"CLASS"' ':' ('"DATA"' | '"VARIABLE"' | '"CONSTRAINT"' | '"OBJECTIVE"' | '"COEFFICIENT"')
24. ROLE::= '"ROLE"' ':' ('"INPUT"' | '"OUTPUT"' |'"OPTIMZATION"')
25. IMPORT\_FROM::= '"IMPORT\_FROM"' ':' ArrayOfStrings
26. INITIALIZE\_FROM::= '"INITIALIZE\_FROM"' ':' ArrayOfStrings
27. EXPORT\_TO::= '"EXPORT\_TO"' ':' ArrayOfStrings
28. INDEX::= '"INDEX"' ':' Identifier
29. FOR\_EACH::= '"FOR\_EACH"' ':' Identifier
30. SCHEMA::= '"SCHEMA"' ':' '{' Field (',' Field)\* '}'
31. Field::= '"' Identifier '"' ':' ('"STRING"' | '"DOUBLE"'| '"INTEGER"' | '"BINARY"' | '"IEEEDOUBLE"')
32. INSTANCE::= (FIELDS ',')? '"INSTANCE"' ':' '[' Record (',' Record)\* ']'
33. FIELDS::= '"FIELDS"' ':' '[' Identifier (',' Identifier)\* ']'
34. Record::= '[' JSONPrimitive (',' JSONPrimitive)\* ']'
35. SINGLETON::= '"SINGLETON"' ':' '{' Item (',' Item)\* '}'
36. Item::= '"' Identifier '"' ':' JSONPrimitive
37. RECIPE::= '"RECIPE"' ':' '{' SQL (',' SQL)\* '}'
38. SQL::= '"' ('"QUERY"' | '"SELECT"' | '"FROM"' | '"WHERE"' | '"JOIN"' | '"UNION"') '"' ':' ArrayOfStrings
39. VariableSchema::= '"SCHEMA"' ':' '{' NameField ',' VariableType ',' (KeyField ',')\* ColumnEncoding ',' (BoundField ',')\* ValueField '}'
40. ConstraintSchema::= '"SCHEMA"' ':' '{' NameField ',' ConstraintType ',' (KeyField ',')\* RowEncoding ',' ConstraintSense ',' RHSField '}'
41. ObjectiveSchema::= '"SCHEMA"' ':' '{' NameField ',' ConstraintType ',' (KeyField ',')\* RowEncoding ',' ConstantField ',' ObjectiveSense ',' ValueField ''}'
42. CoefficientSchema::= '"SCHEMA"' ':' '{' RowEncoding ',' (ColumnEncoding ',' )+ EntryField '}'
43. NameField::= '"' Identifier '"' ':' '"STRING"'
44. VariableType::= '"Type"' ':' ('"CONTINUOUS"' | '"INTEGER"' | '"BINARY"')
45. ConstraintType::= '"Type"' ':' ('"LINEAR"' | '"QUADRATIC"')
46. ObjectiveSense::= '"Sense"' ':' ('"MINIMIZE"' | '"MAXIMIZE"' | '"FREE"')
47. ConstraintSense::= '"Sense"' ':' ('"LE"' | '"EQ"' | '"GE"' | '"<="' | '"=="' | '">="')
48. KeyField::= '"' Identifier '"' ':' ('"STRING"' | '"INTEGER"' )
49. TableauEncoding::= '"' ('Row' | 'Column'[0-9]\*) '"' ':' ('"STRING"' | '"INTEGER"')
50. NumberField::= ('"LowerBound"' | '"UpperBound"' | '"RHS"' | '"Constant"' | '"Entry"' | '"Value"') ':' ('"INTEGER"' | '"DOUBLE"' | '"IEEEDOUBLE"')